So what exactly is Animate Control - "SysAnimate32".
Is there any example how to use this control?
it's a control for playing avi videos(no sound) in a window.
An example from the old forums.
DEF w1 : WINDOW
DEF d1 : Dialog
DEF AniWin : Int
DEF n, h, style : Int
SETID "WS_CHILD",&H40000000
SETID "WS_VISIBLE", &H10000000
SETID "WS_CLIPCHILDREN", &H2000000
SETID "WS_CLIPSIBLINGS", &H4000000
SETID "ACM_OPEN", &H464
SETID "ACS_AUTOPLAY", &H4
SETID "ACS_CENTER", &H1
SETID "ACS_TRANSPARENT", &H2
SETID "RDW_INVALIDATE", &H1
SETID "RDW_ERASE", &H4
style = @ACS_AUTOPLAY|@ACS_CENTER|@ACS_TRANSPARENT|@WS_CHILD|@WS_VISIBLE|@WS_CLIPCHILDREN|@WS_CLIPSIBLINGS
DECLARE "KERNEL32", LoadLibrary ALIAS LoadLibraryA(libname : String), Int
DECLARE "KERNEL32", FreeLibrary(libmodule : Int), Int
DECLARE "USER32", CreateWindowEx ALIAS CreateWindowExA(dwExStyle : Int,Classname : String, lpWindowname : String, dwStyle : Int, x : Int, y : Int, nwidth : Int,nHeight : Int, hParent : Int, hMenu : Int, hInstance : Int, LParam : Int), Int
DECLARE "KERNEL32", GetModuleHandle ALIAS GetModuleHandleA(h : Int), Int
DECLARE "USER32", RedrawWindow(hwnd : Int, lprc : Int, hrng : Int, fuRedraw : Int), Int
h = LoadLibrary("Shell32.dll")
WINDOW w1,0,0,640,480,@SIZE|@MINBOX|@MAXBOX,0,"Fenster",main
CENTERWINDOW w1
AniWin = CreateWindowEx(0,"SysAnimate32","",style,10,100,280,100,w1,0,GetModuleHandle(0),0)
DIALOG d1,0,0,630,40,0x80C80080,w1,"Demo",main
CONTROL d1,"B,Search,10,10,50,25,0x50000000,1"
CONTROL d1,"B,Search Doc, 80, 10, 60, 25, 0x50000000, 2"
CONTROL d1,"B,Search Com, 150, 10, 60, 25, 0x50000000, 3"
CONTROL d1,"B,File cpy , 220, 10, 60, 25, 0x50000000, 4"
CONTROL d1,"B,Copy File, 290, 10, 60, 25, 0x50000000, 5"
CONTROL d1,"B,Delete File, 360, 10, 60, 25, 0x50000000, 6"
CONTROL d1,"B,Empty Bin, 430, 10, 60, 25, 0x50000000, 7"
CONTROL d1,"B,Kill File, 500, 10, 60, 25, 0x50000000, 8"
CONTROL d1,"B,Ende, 570, 10, 60, 25, 0x50000000, 9"
SHOWDIALOG d1
run = 1
WAITUNTIL run = 0
FreeLibrary(h)
CLOSEWINDOW w1
END
SUB main
SELECT @CLASS
CASE @IDCLOSEWINDOW
run = 0
CASE @IDINITDIALOG
CASE @IDCONTROL
SELECT @CONTROLID
CASE 1
SendMessage(AniWin, @ACM_OPEN, h, 150)
CASE 2
SendMessage(AniWin, @ACM_OPEN, h, 151)
CASE 3
SendMessage(AniWin, @ACM_OPEN, h, 152)
CASE 4
SendMessage(AniWin, @ACM_OPEN, h, 160)
CASE 5
SendMessage(AniWin, @ACM_OPEN, h, 161)
CASE 6
SendMessage(AniWin, @ACM_OPEN, h, 162)
CASE 7
SendMessage(AniWin, @ACM_OPEN, h, 163)
CASE 8
SendMessage(AniWin, @ACM_OPEN, h, 164)
CASE 9
run = 0
ENDSELECT
RedrawWindow(AniWin, 0, 0, @RDW_INVALIDATE|@RDW_ERASE)
ENDSELECT
RETURN
LarryMc
I think that might be something like this....
Thanks Larry :)