hello,
Is it possible to detect mouse event on a statictext (mouse over or mouse clic) ?
On pure basic i use a flag (ss_notify)...
You will still use the SS_NOTIFY style, then you will receive the mouse click notification just like you would a button.
This is the static example I gave in your other post with basic click checking:
def run:INT
def win:window
const SS_CENTER = 0x1
const SS_RIGHT = 0x2
const SS_SUNKEN = 0x1000
const SS_NOTIFY = 0x100
const WS_THICKFRAME = 0x40000
const WS_DLGFRAME = 0x400000
declare import,GetSysColor(nIndex:INT),UINT
openwindow win,0,0,640,400,@SIZE|@MINBOX|@MAXBOX,0,"Static Demo",&mainwindow
setwindowcolor win,GetSysColor(15)
control win,@static,"Testing bordered static style",50,50,500,25,@BORDER|SS_CENTER|SS_NOTIFY,1
control win,@static,"Testing sunken static style",50,100,500,25,SS_SUNKEN|SS_CENTER|SS_NOTIFY,2
control win,@static,"Testing bordered sunken static styles",50,150,500,25,@BORDER|SS_SUNKEN|SS_CENTER|SS_NOTIFY,3
control win,@static,"Testing right static style",50,200,500,25,WS_DLGFRAME|SS_RIGHT|SS_NOTIFY,4
control win,@static,"Testing thick frame style",50,250,500,25,WS_THICKFRAME|SS_NOTIFY,5
run = 1
waituntil run=0
closewindow win
end
sub mainwindow
select @MESSAGE
case @IDCLOSEWINDOW
run = 0
case @IDCONTROL
select @CONTROLID
case 1
messagebox win,"Clicked static control 1","Static Demo"
case 2
messagebox win,"Clicked static control 2","Static Demo"
case 3
messagebox win,"Clicked static control 3","Static Demo"
case 4
messagebox win,"Clicked static control 4","Static Demo"
case 5
messagebox win,"Clicked static control 5","Static Demo"
endselect
endselect
return
endsub
very good !
thanx again for reply.