autodefine "off"

$include "windowssdk.inc"
$include "printer.iwb"

TYPE MYINFO
	STRING name
	UINT millisec
ENDTYPE
	MYINFO WaitInfo

'--- used to position Print dialog in centre of window ---
WaitInfo.name="Print"
WaitInfo.millisec=500

UINT T1=ET_Thread(&PositionDialog,&WaitInfo)

STRING PrinterName=SelectPrinter()

IF T1<>0 then
	CloseHandle(T1)
ENDIF

SUB PositionDialog(POINTER infoptr),INT
	STRING title
	UINT ms,cnt=0
	UINT hWnd=0
	UINT left,top,width,height
	WINRECT lpRect
	SETTYPE infoptr,MYINFO
	ms=#infoptr.millisec
	title=#infoptr.name	
WHILE (hWnd=0) AND (cnt<ms)
	Sleep(1)
	cnt++
	hWnd=FindWindow(NULL,title)
ENDWHILE
IF (cnt<ms)
	GetWindowRect(hWnd,&lpRect)
	GETSCREENSIZE width,height
	left=(width-(lpRect.right-lpRect.left))/2
	top=(height-(lpRect.bottom-lpRect.top))/2
	SetWindowPos(hWnd,0,left,top,0,0,SWP_NOSIZE)
ENDIF
RETURN 0
ENDSUB

SUB ET_Thread(Uint subAsThread,pointer subParam),UINT
	UINT threadHandle,tmpHandle
	threadHandle=CreateThread(0,0,subAsThread,subParam,0x4,tmpHandle)
IF threadHandle<>0 THEN ResumeThread(threadHandle)
	RETURN threadHandle
ENDSUB