/*
EBASIC example program
Creating a window and adding a basic menu

Compile as a WINDOWS target
*/

REM define a window variable
DEF w1 as WINDOW
REM a variable to keep track of a checked menu
DEF bChecked as INT
REM open the window
OPENWINDOW w1,0,0,350,350,@MINBOX|@MAXBOX|@SIZE,0,"Simple Window",&main
REM define the menus
BEGINMENU w1
    MENUTITLE "Option"
        MENUITEM "Print", 0, 1
        MENUITEM "Quit", 0, 2
        SEPARATOR
        MENUITEM "Check me", 0, 3
ENDMENU

REM print a message
PRINT w1,"Hello World "
REM when w1 = 0 the window has been closed
WAITUNTIL w1 = 0
END
'---
SUB main
SELECT @MESSAGE
	CASE @IDCREATE
		CENTERWINDOW w1
    CASE @IDCLOSEWINDOW
        REM closes the window and sets w1 = 0
        CLOSEWINDOW w1
    CASE @IDMENUPICK
        SELECT @MENUNUM
            CASE 1: ' user selected Print
                PRINTWINDOW w1
            CASE 2: ' user selected Quit
                CLOSEWINDOW w1
            CASE 3: ' toggle a checkmark
                bChecked = (bChecked = FALSE)
                CHECKMENUITEM w1, 3, bChecked
        ENDSELECT
ENDSELECT
RETURN
ENDSUB